Clara & Pong 15

First things first: Die deutsche Fassung der aktuellen Episode findet ihr hier: http://clarapong.com/comic/dresscode/  – oder auf das Bild klicken.

p15

Jetzt zum „making of“! Heute wird es mal etwas ausführlicher und technischer: Die fertig getuschte Vorzeichnung muss gescannt (gescanned? gescant?) und für das Kolorieren am Rechner vorbereitet werden. Wie geht das im Detail?

Meine Vorzeichnungen mache ich auf A3-Papier. Großartig wäre ein A3-Scanner, hab ich aber leider nicht. Von daher scanne ich beide Hälften der Seite mit 600 dpi und füge sie am Rechner zusammen. Ich habe eine Weile nach automatischen Tools dafür gesucht, letztendlich bin ich aber auf manuelles Pixelschubsen zurückgefallen.

Für die Verarbeitung der Scans benutze ich GIMP. Zum Malen und Zeichnen mit dem Tablet ist das zwar nicht so toll, aber für diesen Schritt funktioniert es super. Vor allem auch deshalb, weil ich für die einzelnen Schritte ein Skript gebastelt habe:

  1. Die geladenen beiden Layer mit den Scanhälften von Graustufen nach RGB umwandeln
  2. den rechten Layer (der auf dem Kopf steht, weil ich das Blatt gedreht habe) um 180 Grad drehen
  3. Schon mal grob automatisch ausrichten, so dass die Hälften in etwa aneinanderpassen
  4. Per Schwellwert die Bleistiftreste entfernen, so dass ein knackiges S/W-Bild entsteht
  5. das Weiß durch Transparenz ersetzen
  6. einen separaten weißen Hintergrundlayer anlegen
  7. einen Layer obendrauf legen, in den ich die Korrekturen male
  8. Schwarz und weiß als Malfarben festlegen.

Nach der Feinjustierung der rechten Seite sieht das dann so aus:

scanprep-screenshot

Das Skript hänge ich für alle Wahnsinnigen, die sich auf Gimp-Programmierung einlassen möchten, hinten an diesen Beitrag an.

In dem oberen Layer („fixes“) mache ich mit schwarz und weiss meine Korrekturen. Ist übrigens auch beim Tuschen irre entspannend, wenn ich weiß, dass die übelsten Fehler hinterher noch begradigt werden können 🙂

Wenn ich fertig bin, füge ich die Ebenen zusammen, wandle weiss nach transparent, und exportiere das Ganze in halber Auflösung (300 dpi) als Outlines. Dafür hab ich auch wieder ein kleines Skript. Zum Kolorieren dann ein anderes mal mehr.

 

Soooo, und hier für die Hartgesottenen die beiden Skripte. Die werden mit der Endung .scm im passenden Ordner abgelegt (auf meinem Mac ist das ~/Library/Application\ Support/Gimp/2.8/scripts/)

1) script-fu-clarapong-prepare-scans.scm:

; assumes two halves of the scan have been opened as layers:
 ; ScanL.tif in layer 1, ScanR.tif (upside down) in layer 2

(define (script-fu-clarapong-prepare-scans inImage inThreshold)

(gimp-image-undo-group-start inImage)

; get the layers
 (let* (
 (scanLLayer (car (gimp-image-get-layer-by-name inImage "ScanL.tif")))
 (scanRLayer (car (gimp-image-get-layer-by-name inImage "ScanR.tif")))
 (black '(0 0 0))
 (white '(255 255 255))
 )

; change image mode to RGB
 (gimp-image-convert-rgb inImage)

; apply threshold
 (gimp-threshold scanLLayer inThreshold 255)
 (gimp-threshold scanRLayer inThreshold 255)

; rotate layer 2 by 180 degrees
 (gimp-item-transform-rotate-simple scanRLayer ROTATE-180 TRUE 0 0)

; shift right layer to roughly match left scan halve, and resize image to layers
 (gimp-layer-translate scanRLayer 4665 0)
 (gimp-image-resize-to-layers inImage)

; convert white to transparency
 (plug-in-colortoalpha 1 inImage scanLLayer white)
 (plug-in-colortoalpha 1 inImage scanRLayer white)

; add bottom layer filled with white
 (let* (
 (bgLayer (car (gimp-layer-new-from-visible inImage inImage "bg")))
 )
 (gimp-drawable-fill bgLayer WHITE-FILL)
 (gimp-image-insert-layer inImage bgLayer 0 2)
 )

; add layer on top for fixes

(let* (
 (fixesLayer (car (gimp-layer-new-from-visible inImage inImage "fixes")))
 )
 (gimp-drawable-fill fixesLayer TRANSPARENT-FILL)
 (gimp-image-insert-layer inImage fixesLayer 0 0)
 )

; set foreground color to black, background color to white
 (gimp-context-set-foreground black)
 (gimp-context-set-background white)
 (gimp-displays-flush)
 )

(gimp-image-undo-group-end inImage)
 )

(script-fu-register
 "script-fu-clarapong-prepare-scans"              ; func name
 "<Image>/Filters/Kolja/_ClaraPong Prepare Scans" ; menu label
 "With two scans loaded into layers, prepare for final adjustment and retouching"   ; description
 ""                                               ; author
 "(c) Kolja"                                      ; copyright
 "July 2016"                                      ; date created
 ""                                               ; image type the script works on
 SF-IMAGE      "Image"   0                        ; the current image
 SF-ADJUSTMENT    "B/W threshold value"    '(180 0 256 1 10 0 SF-SPINNER)
 )

 

2) script-fu-clarapong-prepare-outlines.scm:

; assumes layers as created by clarapong-prepare-scans script

(define (script-fu-clarapong-prepare-outlines inImage)

(gimp-image-undo-group-start inImage)

; get the layers
 (let* (
 (bgLayer (car (gimp-image-get-layer-by-name inImage "bg")))
 (white '(255 255 255))
 )

; make bg layer invisible
 (gimp-item-set-visible bgLayer FALSE)

(let* (
 (fullWidth  (car (gimp-image-width  inImage)))
 (fullHeight (car (gimp-image-height inImage)))
 (resolution (gimp-image-get-resolution inImage))
 (layer (car (gimp-image-merge-visible-layers inImage CLIP-TO-IMAGE)))        ; flatten everything visible into one layer
 )

; convert white to transparency
 (plug-in-colortoalpha 1 inImage layer white)

; scale to 50%, adjust DPI
 (gimp-image-scale inImage (/ fullWidth 2) (/ fullHeight 2))
 (apply gimp-image-set-resolution inImage (map / resolution '(2 2)))
 )

(gimp-displays-flush)
 )

(gimp-image-undo-group-end inImage)
 )

(script-fu-register
 "script-fu-clarapong-prepare-outlines"           ; func name
 "<Image>/Filters/Kolja/_ClaraPong Prepare Outlines" ; menu label
 "With layers as given by Prepare Scans, collapses everything into half-resolution outlines"   ; description
 ""                                               ; author
 "(c) Kolja"                                      ; copyright
 "September 2016"                                 ; date created
 ""                                               ; image type the script works on
 SF-IMAGE      "Image"   0                        ; the current image
 )
Advertisements

Ein Gedanke zu “Clara & Pong 15

Kommentar verfassen

Trage deine Daten unten ein oder klicke ein Icon um dich einzuloggen:

WordPress.com-Logo

Du kommentierst mit Deinem WordPress.com-Konto. Abmelden /  Ändern )

Google+ Foto

Du kommentierst mit Deinem Google+-Konto. Abmelden /  Ändern )

Twitter-Bild

Du kommentierst mit Deinem Twitter-Konto. Abmelden /  Ändern )

Facebook-Foto

Du kommentierst mit Deinem Facebook-Konto. Abmelden /  Ändern )

w

Verbinde mit %s